GROUP 1. Run title and other preliminaries
TEXT(Wall Jet K-E Turbu Model; Parab   
TITLE
  DISPLAY
  The application considered is the self-preserving turbulent
  plane jet. This flow is of interest for many engineering
  applications including for example, film cooling and heating and
  ventilating. Here, the wall jet is described as a steady
  incompressible jet of fluid emanating from a narrow slot and
  blowing tangentially over a rigid plane adiabatic surface. The
  injected fluid is heated above the ambient temperature. The flow
  in a turbulent wall jet can be regarded as that of a wall layer
  and  a free shear layer interacting with each other, and
  therefore the wall jet is a much more complex flow than say a
  conventional turbulent boundary layer or a free turbulent jet.
 
  ENDDIS
 
  Like the free jet (see case 150 for example) the wall jet in
  stagnant surroundings becomes self-similar after a certain
  development region. In the wall jet the characteristic scales are
  the velocity half-width, d, and the maximum velocity, Wm. In the
  self-similar region, the jet spreads linearly and Wm decays as
  z**(-m). Here the exponent m must be determined empirically
  because the constancy of the flux of momentum does not hold in
  the wall jet. Experiments indicate that m is slightly less than
  -1/2.
 
  Dynamic similarity of the thermal field can be expected, implying
  a linear growth of the temperature half-width, dt, and a maximum
  temperature excess which decays as z**-(1+m). Therefore,
  this temperature excess and Wm can be expected to decay at
  approximately the same rate.
 
  The calculations are started at the jet origin with arbitrary
  initial profiles; and the calculation extends downstream until
  self-similarity is attained. The calculations are made with 50
  grid nodes across the jet and a forward step size of 10% of the
  local width.
 
  The turbulent Prandtl number is set equal to 0.86 and the
  molecular Prandtl number to 0.71.
 
  The k-e turbulence model is used with the standard set of model
  constants. This model considerably overpredicts the spreading
  rate of the jet. To predict correctly the wall-jet development,
  the model must be extended to account for the wall's damping of
  the lateral velocity fluctuations.
REAL(WFREE,TFREE,TKEIN,EPSIN,GMIXL,WJET,REYNO,HSLOT,TJET,FRA)
REYNO=18000.;HSLOT=6.E-3;WJET=54.;TJET=1.0;WFREE=0.0;TFREE=0.0
 
    GROUP 4. Y-direction grid specification
NY=50;YVLAST=1.25*HSLOT
YFRAC(1)=-1.000E+00;YFRAC(2)=1.200E-02
YFRAC(3)=1.000E+00;YFRAC(4)=3.000E-03
YFRAC(5)=2.000E+00;YFRAC(6)=2.000E-03
YFRAC(7)=2.000E+00;YFRAC(8)=3.000E-03
YFRAC(9)=2.000E+00;YFRAC(10)=3.500E-03
YFRAC(11)=2.000E+00;YFRAC(12)=6.500E-03
YFRAC(13)=2.000E+00;YFRAC(14)=1.000E-02
YFRAC(15)=2.000E+00;YFRAC(16)=1.250E-02
YFRAC(17)=2.000E+00;YFRAC(18)=1.500E-02
YFRAC(19)=4.000E+00;YFRAC(20)=2.000E-02
YFRAC(21)=2.000E+00;YFRAC(22)=2.000E-02
YFRAC(23)=2.000E+01;YFRAC(24)=2.800E-02
YFRAC(25)=8.000E+00;YFRAC(26)=2.500E-02
   **Linear Expansion AZYV=1.0 ZWADD=YVLAST(INLET)/DYLDZ
    DYLDZ=.09*2.5=.2625
AZYV=1.0;ZWADD=3.3333E-2
 
    GROUP 5. Z-direction grid specification
NZ=8;AZDZ=PROPY;PARAB=T
 
    GROUP 7. Variables stored, solved & named
SOLUTN(P1,Y,Y,N,N,N,Y);SOLUTN(V1,Y,Y,N,N,N,Y);SOLUTN(W1,Y,Y,N,N,N,Y)
SOLUTN(KE,Y,Y,N,N,N,Y);SOLUTN(EP,Y,Y,N,N,N,Y)
NAME(H1)=TEMP;SOLUTN(TEMP,Y,Y,N,N,N,Y)
STORE(ENUT);VARMIN(KE)=1.E-10;VARMIN(EP)=1.E-10
 
    GROUP 8. Terms (in differential equations) & devices
DIFCUT=0.0
TERMS(TEMP,N,Y,Y,Y,Y,Y)
 
    GROUP 9. Properties of the medium (or media)
PRT(TEMP)=0.86;ENUL=WJET*HSLOT/REYNO
  ** Select Prandtl-Kolmogorov: Group 9/Sect. 5 of GREX3
  ** Select k-e Length scale: Group 9/Sect. 12 of GREX3
EL1=KE15DEP;ENUT=PRKOLM
 
    GROUP 11. Initialization of variable or porosity fields
  ** Inside the nozzle
  The following initializations of the fields at the first forward
  step are done solely to promote convergence. The inlet conditions
  are set in Group 13.
PATCH(INSIDE,INIVAL,1,1,1,42,1,1,1,1);INIT(INSIDE,W1,0.0,WJET)
  ** Inlet Intensity of 1%
TKEIN=0.0001*WJET*WJET
INIT(INSIDE,KE,0.,TKEIN)
  ** Inlet dissipation rate = .1643*k**1.5/Lm
GMIXL=0.035*HSLOT;EPSIN=TKEIN**1.5/GMIXL*.1643
INIT(INSIDE,EP,0.,EPSIN);INIT(INSIDE,TEMP,0.,TJET)
  ** Outside the nozzle
PATCH(OUTSIDE,INIVAL,1,1,43,NY,1,1,1,1)
INIT(OUTSIDE,W1,0.,WFREE);INIT(OUTSIDE,TEMP,0.,TFREE)
 
    GROUP 13. Boundary conditions and special sources
  ** Outer Boundary
PATCH(OUTER,NORTH,1,1,NY,NY,1,NZ,1,1)
COVAL(OUTER,P1,1.E4,0.0);COVAL(OUTER,TEMP,ONLYMS,TFREE)
COVAL(OUTER,W1,ONLYMS,0.0);COVAL(OUTER,V1,ONLYMS,0.0)
COVAL(OUTER,KE,ONLYMS,1.E-10);COVAL(OUTER,EP,ONLYMS,1.E-5)
  ** Inlet Boundary
PATCH(PROF,LOW,1,1,1,42,1,1,1,1)
COVAL(PROF,P1,FIXFLU,WJET);COVAL(PROF,W1,ONLYMS,WJET)
  ** Inlet Intensity of 1%
COVAL(PROF,KE,ONLYMS,TKEIN);COVAL(PROF,EP,ONLYMS,EPSIN)
COVAL(PROF,TEMP,ONLYMS,TJET)
  ** Activate source terms for k and e: Group 13 of GREX3
PATCH(KESO,PHASEM,1,1,1,NY,1,NZ,1,1)
COVAL(KESO,KE,KESOURCE,KESOURCE);COVAL(KESO,EP,KESOURCE,KESOURCE)
  ** Wall-Boundary
WALL (WALL1,SOUTH,1,1,1,1,1,NZ,1,1)
 
    GROUP 14. Downstream pressure for PARAB=T
IPARAB=1
 
    GROUP 16. Termination of iterations
LITHYD=20
 
    GROUP 17. Under-relaxation devices
RELAX(V1,FALSDT,100.0);RELAX(W1,FALSDT,100.)
RELAX(KE,FALSDT,50.0);RELAX(EP,FALSDT,50.)
 
    GROUP 19. Data communicated by SATELLITE to GROUND
  ** Select strain-rate for turbulence production term
DWDY=T;FRA=0.05
DZW1=FRA
EL1A=0.01;EL1B=WFREE;EL1C=WJET
 
    GROUP 21. Print-out of variables
OUTPUT(P1,Y,Y,Y,Y,Y,Y);OUTPUT(V1,Y,Y,Y,Y,Y,Y)
OUTPUT(W1,Y,Y,Y,Y,Y,Y);OUTPUT(KE,Y,Y,Y,Y,Y,Y)
OUTPUT(EP,Y,Y,Y,Y,Y,Y);OUTPUT(TEMP,Y,Y,Y,Y,Y,Y)
 
    GROUP 22. Monitor print-out
IZMON=1;IYMON=12
 
    GROUP 23. Field print-out and plot control
NPLT=2;ITABL=2;IPLTL=40
NYPRIN=2;NZPRIN=2
PATCH(IZEQNZ,PROFIL,1,1,1,NY,1,NZ,1,1)
PLOT(IZEQNZ,W1,0.,0.0);PLOT(IZEQNZ,TEMP,0.0,0.0)
PLOT(IZEQNZ,KE,0.0,0.0)