PHOTON USE
  p
  parphi
 
 
 
 
  msg        LAMINAR 2D BOUNDARY LAYER ON WALL
  msg
  set ref vec 3
  msg   Velocity vectors:
  vec x 1 sh
  msg
  msg Press  to continue
  pause
  vec off;red
  msg        Axial velocity contours:
  con wcrt x 1 fi;.01
  msg
  msg Press  to continue
  pause
  con off;red
  msg        Distribution of the velocity component
  msg        normal to the wall:
  con vcrt x 1 fi;.01
  msg            -
  msg Press  to continue
  pause
  con off;red
  msg        Temperature distribution:
  con h1 x 1 fi;.01
  msg
  msg Press  to continue
  pause
  con off;red
  msg        Pressure contours:
  con p1 x 1 fi;.01
  msg
  msg Press e to END
  enduse
 
    GROUP 1. Run title and other preliminaries
TEXT(2D Laminar B-Layer On A Hot Wall  
TITLE
mesg(PC486/50 time last reported as 1.min
  DISPLAY
  This run shows what happens in a boundary-layer flow adjacent
  to a heated wall. An expanding grid is used in the direction
  normal to the wall so as to match the growth of the boundary
  layer.
 
                        Fixed, zero pressure boundary. W=1.0m/s
  Prescribed  - - - - - - - - - - - - - - - - - - - - - - - - -
  mass inflow
  rate,       ----->             ----->                  ----->
  velocity    ----->             ---->                   ---->
  and         ----->             --->                    -->
  enthalpy    _________________________________________________
           ^  /////////////////////////////////////////////////
          y|                     Wall
           |--->
             z
 
  ENDDIS
 
     Users may like to try changing : the grid-expansion
  rate; the velocity of the fluid at the leading edge
  and the boundary values on the plate.
 
    GROUP 4. Y-direction grid specification
GRDPWR(Y,20,5.0E-4,1.0)
  ** Grid width grows as (axial distance)**0.5
AZYV=0.5;ZWADD=5.0E-04
 
    GROUP 5. Z-direction grid specification
PARAB=T
  ** Z-direction distances vary as IZ**2.0
GRDPWR(Z,20,0.1,2.0)
 
    GROUP 7. Variables stored, solved & named
SOLVE(P1,V1,W1,H1)
 
    GROUP 8. Terms (in differential equations) & devices
TERMS(H1,N,Y,Y,Y,Y,Y)
 
    GROUP 9. Properties of the medium (or media)
ENUL=1.E-5;PRNDTL(H1)=0.7
 
    GROUP 13. Boundary conditions and special sources
 
  ** South wall
WALL (plte,SOUTH,1,1,1,1,1,NZ,1,1)
COVAL(plte,H1,1.0,0.0);COVAL(plte,W1,1.0,0.0)
 
  ** Open North boundary
PATCH(HIGHY,CELL,1,1,NY,NY,1,NZ,1,1)
COVAL(HIGHY,P1,FIXP,0.0);COVAL(HIGHY,H1,ONLYMS,1.0)
COVAL(HIGHY,W1,ONLYMS,1.0);COVAL(HIGHY,V1,ONLYMS,0.0)
 
  ** Upstream boundary
INLET(UPSTREAM,LOW,1,1,1,NY,1,1,1,1)
VALUE(UPSTREAM,P1,1.0);VALUE(UPSTREAM,W1,1.0)
VALUE(UPSTREAM,H1,1.0)
 
    GROUP 14. Downstream pressure for PARAB=T
IPARAB=1
 
    GROUP 16. Termination of iterations
LITHYD=10
 
    GROUP 22. Spot-value print-out
IYMON=5
 
    GROUP 23. Field print-out and plot control
NZPRIN=NZ/2;NPLT=1;TSTSWP=LITHYD/2
  ** Cross-stream profiles
PATCH(FIXEDZ,PROFIL,1,1,1,NY,1,NZ,1,1)
PLOT(FIXEDZ,W1,0.0,0.0);PLOT(FIXEDZ,H1,0.0,0.0)
 
  ***actdem***
mesg(Press  to continue
readvdu(ans,char,n)
do ii=1,5
+ mesg(
enddo
mesg( Initial data that can be changed:
mesga(  Grid expansion rate = 0.5
mesg(  Wall enthalpy = 0.
mesg(  Fluid velocity at the leading edge = 1.m/s
mesga( Do you want to change settings (y/n)? (Default n)
readvdu(ans,char,n)
 
if(:ans:.eq.y) then
+ real(rt1)
+ do ii=1,5
+   mesg(
+ enddo
+ mesga(  Grid expansion rate is 0.5. OK? If not, insert new value.
+ readvdu(rt1,real,0.5)
+ AZYV=rt1; ZWADD=5.0E-04
 
+ do ii=1,5
+   mesg(
+ enddo
+ mesga( Wall enthalpy is set to 0. OK? If not, insert new value.
+ readvdu(rt1,real,0.)
+ COVAL(plte,H1,1.0,rt1);COVAL(plte,W1,1.0,0.0)
 
+ do ii=1,5
+   mesg(
+ enddo
+ mesg( Fluid velocity at the leading edge is 1.m/s. OK?
+ mesga( If not, insert new value.
+ readvdu(rt1,real,1.)
+ VALUE(UPSTREAM,P1,rt1);VALUE(UPSTREAM,W1,rt1)
endif
 
IDISPA=1; TSTSWP=-1
selref=t; resfac=1.e-2