TALK=T;RUN( 1, 1) 130 rotating disc
```
DISPLAY

This case concerns steady laminar flow near a rotating disk
in an infinite atmosphere.

The Reynolds number is sufficiently high for a self-similar
boundary layer to develop, as is shown by the facts that:
* the axial velocity w1,
* the dimensionless radial velocity v1/radius, and
* the dimensionless circumferential velocity u1/radius
* are all functions of axial distance alone.

Because the axial-direction grid spacing and the false-time-step
relaxation depend on the rotation speed omega, omega may be varied
over a wide range without other settings having to be changed.

ENDDIS
PHOTON USE
p

1 5000

con v1 x 1 fi;0.001
pause
con dimv x 1 y 1 99 z 1 20 fi;0.001
pause
con dimu x 1 fi;0.001
pause
con dimw x 1 y 1 100 z 1 19 fi;0.001

ENDUSE
TEXT(Steady laminar rotating-disc flow)
REAL(OMEGA,RADIUS,REYNO,ROOT)
OMEGA=200000
RADIUS=0.5
REYNO=OMEGA*RADIUS**2/ENUL
ROOT=REYNO**0.5

NX=1;XULAST=0.01                   ! grid and geometry settings
NY=100;NZ=20
YVLAST=RADIUS
ZWLAST=10.0*YVLAST/ROOT

GRDPWR(Y,NY,-YVLAST,1.01)
GRDPWR(Z,NZ,-ZWLAST,1.1)
CARTES=F
SOLVE(P1,U1,V1,W1,TEM1)            ! the variables solved, and how
SOLUTN(P1,Y,Y,Y,P,P,P)
SOLUTN(V1,Y,Y,Y,P,P,P)
SOLUTN(W1,Y,Y,Y,P,P,P)

PATCH(HIGH,CELL,1,1,1,NY,NZ,NZ,1,1)  ! boundary conditions
COVAL(HIGH,P1,FIXVAL,0.0)
COVAL(HIGH,TEM1,ONLYMS,0.0)

IURVAL=-1                            ! signal to ensure u1 setting
PATCH(DISC,LWALL,1,1,1,NY,1,1,1,1)   ! is interpreted
COVAL(DISC, U1, 1.0, OMEGA)          ! as omega * radius
COVAL(DISC, V1, 1.0, 0.0)
COVAL(DISC, TEM1, 1.0, 1.0)

PATCH(OUTLET,CELL,1,1,NY,NY,1,NZ,1,1)
COVAL(OUTLET,P1,FIXVAL,0.0)

RELAX(W1,FALSDT,1.0E-1/OMEGA)    ! omega-dependent under-relaxation
RELAX(V1,FALSDT,1.0E-2/OMEGA)

IYMON=NY/2; IZMON=NZ/2
LSWEEP=1000
TSTSWP=-1
(STORED VAR DIMW IS W1/(:OMEGA:*:RADIUS:/:ROOT:) ) !** InForm
(STORED VAR DIMV IS V1/(:OMEGA:*RV))   !** ensures computation of
(STORED VAR DIMU IS U1/(:OMEGA:*RG))   !** dimensionless quantities
```