GROUP 1. Run title and other preliminaries
TEXT(Trans Heat Conduction-Uniform Fin 
TITLE
  DISPLAY
    Cases 110 to 114 illustrate how "porosity" values may be used
    to introduce not only geometrical data, but also variations in
    thermal conductivity, specific heat and heat-transfer coeff.
    In case 110, the cross-section and other properties are uniform.
    Subsequent cases introduce non-uniformities, by way of porosity,
    one by one.  A sketch of the geometry for case 110 follows:
                   /--/|
                  /**/ |
                 /**/  |
                /**/   |
               /**/  <------- surface in contact with
              |--|     | ^    surrounding fluid
              |**|     | |    at temperature = 0.0
              |**|     | |x
              |**|     | |
        ///// |**|    //////////////////////////////////
       ////// |**|   //////////////////////////////////
      /////// |**|  ////// base at temperature = 1.0 /
     //////// |**| //////////////////////////////////
    ///////// |--|//////////////////////////////////
             y---->
l(pause
    That it is possible to act in this way does not mean that it
    is necessary or even recommended.
 
    These cases were very early entries to the library, and have been
    retained for historical interest. However, the treatment of H1
    as though it represented temperature is valid only for a
    constant specific heat; and, in the final case of the series,
    the specific heat is supposed to vary.
 
    Nowadays, use of TEM1 is recommended rather than H1; and In-Form
    provides a much more convenient way of introducing variations of
    properties and boundary conditions.
 
  ENDDIS
 
   ** The locally-defined variables are as follows:
 
      COEF           Surface heat-transfer coefficient
      COND1          Thermal conductivity
      SPHT1          Specific heat
 
REAL(COEF,COND1,SPHT1)
COND1=400.0; COEF=1.0E01; SPHT1=500.0
 
    GROUP 2. Transience; time-step specification
   ** The transient lasts for 20 seconds
STEADY=F; GRDPWR(T,100,20.0,1.0)
 
    GROUP 3. X-direction grid specification
   ** The fin length is 0.1 meters
GRDPWR(X,20,0.1,1.0)
 
    GROUP 4. Y-direction grid specification
   ** The fin thickness is twice YVLAST
YVLAST=0.001
 
    GROUP 7. Variables stored, solved & named
SOLVE(TEMP)
 
    GROUP 8. Terms (in differential equations) & devices
   ** Built-in source and convection terms are cut out
TERMS(TEMP,N,N,Y,Y,P,P)
 
    GROUP 9. Properties of the medium (or media)
ENUL=1.0; RHO1=1.E4; PRNDTL(TEMP)=SPHT1*ENUL*RHO1/COND1
 
    GROUP 11. Initialization of variable or porosity fields
FIINIT(TEMP)=1.0
 
    GROUP 13. Boundary conditions and special sources
   ** Uniform zero temperature at the fin surface
PATCH(SURFACE,FREEN,1,NX,1,1,1,1,1,LSTEP)
COVAL(SURFACE,TEMP,COEF,0.0)
 
   ** Fixed temperature at the fin root
WALL(ROOT,WEST,1,1,1,1,1,1,1,LSTEP)
COVAL(ROOT,TEMP,1.0/PRNDTL(TEMP),1.0)
 
    GROUP 15. Termination of sweeps
   ** One sweep suffices to yield the exact solution
LSWEEP=1
SPEDAT(SET,GXMONI,TRANSIENT,L,F)
    GROUP 21. Print-out of variables
NPRMNT=LSTEP
    GROUP 23. Field print-out and plot control
OUTPUT(TEMP,Y,Y,N,N,N,N)
NXPRIN=NX/10; NTPRIN=LSTEP/2; ORSIZ=0.2
PATCH(FIXEDT,PROFIL,1,NX,1,1,1,1,1,LSTEP)
PLOT(FIXEDT,TEMP,0.0,1.0)
PATCH(FINTIP,PROFIL,NX,NX,1,1,1,1,1,LSTEP)
PLOT(FINTIP,TEMP,0.0,0.0)
    GROUP 24. Dumps for restarts